Flash是目前应用最为广泛的支持高复杂度程序控制的矢量课件制作软件。它集绘画、设计、编程、制作、编辑、合成和高品质输出为一体,利用它可以方便、快捷地制作出各种各样的矢量动画效果,可以制作各种基本图形、交互式动画、MTV、课件、复杂的Web应用程序等方面的应用。
访问属性
AS3为类和类成员引入了两个新的访问属性来扩展AS2中的private访问属性。在AS3中,现在有下面的访问控制属性:
public
protected
private
internal (默认)
public:public 属性和AS2中一样。在任何地方定义的public属性,能在任何地方和被任何成员引用。构造器必须定义成public。应用程序类必须是public 的。protected:protected是一个新的属性。被protected指定的成员,只能被其本身或其子类访问。如果外部类尝试访问被 protected的成员,将会抛出编译错误。类和构造器不能被声明为protected。
private:AS2中已经有 private属性,但是在AS2中,子类成员可以任意的访问父类的private成员。现在在AS3中,private属性只能在类内部被访问,其他类 包括子类都不能直接访问此成员。也就是说,在子类中可以定义一个名称和父类某成员名称一样的成员,只要父类的此成员是声明为private的。类和构造器 不能被定义为private。
internal:internal和public比较类似,不同的地方在于类成员只能被同一个包中的成员 所访问,而其他包中的成员不能访问。internal是除了构造器以外的所有类和类成员的默认声明。辅助类的访问控制有所不同。由于辅助类不属于任何 包,internal的声明将限制其被访问只能是当前文件之内。注意:主类不能继承辅助类,只有辅助类能继承辅助类,并且要在同一个文件内。访问控制的错 误,并不仅仅是编译时错误,有时候也是运行时错误,在AS2中用来访问隐藏方法的方式,在AS3中不能用了,如:
package {
import flash.display.Sprite;
// 应用类必须定义成public (默认是internal)
public class AccessControl extends Sprite {
// 构造器总是public的
function AccessControl() {
// 只有在这个文件中才能访问辅助类
var helper:Helper = new Helper();
trace(helper.pubNum); // OK
// trace(helper.protNum); // Error - 错误,不能访问protected成员
// trace(helper.privNum); // Error - 错误,不能访问private成员
trace(helper.interNum); // OK
}
}
}
// 辅助类默认是internal
class Helper {
// public声明允许在任何地方被访问
// 变量通常被设置为private的,然后通过声明public的get set方法来访问
public var pubNum:Number = 1;
// protected声明只允许在子类中被访问
protected var protNum:Number = 2;
// private声明只能在类内部被访问
private var privNum:Number = 3;
// internal声明只允许在同一个包中被访问
// 但是对于辅助类来说,只能在同一个文件类被访问
internal var interNum:Number = 4;
// 构造器永远都是public的
function Helper() {
}
}
// 子辅助类默认是internal的
// 可以继承其他辅助类
class SubHelper extends Helper {
// 构造器,public
function SubHelper() {
trace(pubNum); // OK
trace(protNum); // OK - 继承得到的
// trace(privNum); // Error - 不能访问private
trace(interNum); // OK
}
}
Flash课件界面应尽量做到简明扼要。在教学内容的输出上要精心设计屏幕。每一屏上的例句或概念不要太多太复杂。插图要适当,太花哨的屏幕易使学生分散注意力和使人头晕。而运用Flash课件制作来创设多窗口、图标选择及简表等形式使教学内容条理清楚,增强其可读性。